How to make my sun appear far away in VR

Question

I am attempting to add VR compatibility to my game, please could you help me figure out how to better control the multiple cameras in my scene regarding the head tracking and movement from VR devices?

I’m using Unity v2019.4, and not using the new VR Plugin system. In my XR Settings I have Virtual Reality Supported ticked and have the Oculus and OpenVR virtual reality SDKs.

I have three cameras in my scene, at the following Depth levels:

2 = Main Camera (Depth only) which shows everything except my sun and skybox

1 = A Sun Camera (Depth only) showing only my sun layer

0 = A Background Camera (SkyBox) showing my custom skybox

The reason I render the sun on a separate camera is to give the effect of a very distant object. The sun camera is sat close to the sun, but when I move in the scene the sun never gets any closer giving the illusion of it being far out there in space. This works great in non-VR, but in VR if I move my head forward or to the side, the sun camera also moves and so breaks the illusion of the distant sun.

I have tried playing around with settings and done a lot of searching, but I cannot figure out how to stop the "local" movement in my sun camera. Any ideas?

Answer 1

If you can modify the shaders used by your sun, you can neutralize the parallax of your camera in the vertex shader.

Here's the default vertex shader you get from Unity when making a new unlit effect (I presume the sun is unlit since it's a source of light, not something that reflects light significantly):

v2f vert (appdata v)
{
    v2f o;

    // This line combines the object's transform, the camera's viewpoint,
    // and the perspective projection into one step.
    o.vertex = UnityObjectToClipPos(v.vertex);
    // That's the only part we're going to change.

    o.uv = TRANSFORM_TEX(v.uv, _MainTex);
    UNITY_TRANSFER_FOG(o,o.vertex);
    return o;
}

We can change that to this:

v2f vert (appdata v)
{
    v2f o;

    // First, apply the object's transformation in the world.
    float4 pos = mul(unity_ObjectToWorld, v.vertex);

    // Zero out the w component, so we're not affected by the camera position
    // in the next step - we behave as though the camera is always at (0, 0, 0).
    pos.w = 0;
    // Then apply the camera's rotation.
    pos = mul(UNITY_MATRIX_V, pos);

    // Restore the w component so we project correctly...
    pos.w = 1;
    // ...and apply the perspective projection.
    o.vertex = mul(UNITY_MATRIX_P, pos);
    
    // The rest of the shader can remain unchanged.
    o.uv = TRANSFORM_TEX(v.uv, _MainTex);
    UNITY_TRANSFER_FOG(o,o.vertex);
    return o;
}