How does the following code generate a full screen quad?

Question

How does this

struct Output
{
    float4 position_cs : SV_POSITION;
    float2 texcoord : TEXCOORD;
};

Output main(uint id: SV_VertexID)
{
    Output output;
    output.texcoord = float2((id << 1) & 2, id & 2);
    output.position_cs = float4(output.texcoord * float2(2, -2) + float2(-1, 1), 0, 1);
    return output;
}

and this

pImmediateContext->VSSetShader(fxaaVS, ..., ...);
pImmediateContext->IASetPrimitiveTopology(D3D11_PRIMITIVE_TOPOLOGY_TRIANGLELIST);
pImmediateContext->Draw(3, 0);

generate a Full Screen Quad?

1. It has only three vertices b(provided quad has 4 vertices)
2. the positions produced are also not like a (half of a) quad.

Looking at this, i might be confused between a quad and a full screen triangle.

Answer 1

it doesn't generate a quad, instead it generates a fullscreen triangle.

The outputs end up as:

output[0].texcoord = float2(0,0); 
output[0].position_cs = float4(-1, 1, 0, 1);

output[1].texcoord = float2(2,0);  
output[1].position_cs = float4(3, 1, 0, 1);

output[2].texcoord = float2(0,2); 
output[2].position_cs = float4(-1, -3, 0, 1);

It goes beyond the edges of the screen but any part outside will get clipped by the rasterizer stage. Doing this avoid double coverage of evaluated pixel on the diagonal you get with 2 triangles.